*
* CORRIGE TP N°01 
* ~~~~~~~~~~~~~~~
*
* les options d'affichage du défilement des calculs
  opti echo 1 ;
* opti echo 0 ;
* ACTIVATION OU DESACTIVATION DE L'affichage du maillage
  GRAPH = VRAI ;
* GRAPH = FAUX ;
*
** pour avoir les résultats dans un fichier
* ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
  listing='N'; 

* QUESTION 01 (01 point)
* ~~~~~~~~~~~~~~~~~~~~~~~
* les options générales des calculs 
 opti dime 2 mode plan cont ;
 opti elem qua4 ;
 MESS 'MODELISATION 2D par EF d une PLAQUE en CONT PLANES' ;
*
* QUESTION 02 (02 points)
* ~~~~~~~~~~~~~~~~~~~~~~~ 
* la géometrie
 b = 50. ;  nlarg = 5 ;
 l = 200.;  nlong = 20 ; 
*
* points
 pa = 0. 0. ; pb = l 0. ; pc = l b ; pd = 0. b ;
*lignes
 l1 = d nlong pa pb ; l2 = d nlarg pb pc ;
 l3 = d nlong pc pd ; l4 = d nlarg pd pa ;
*contour de plaque
 ct1 = l1 et l2 et l3 et l4 ;
* le maillage
 S1 = surf ct1 plan coul bleu ;
 si graph ;
 TITR 'MAILLAGE DE LA PLAQUE' ;
 trac S1 ;
 finsi ;
 NES1 = NBEL S1 ;NOES1 = NBNO S1 ;
 MESS '                   ' ;
 MESS 'NOMBRE D ELEMENTS ='NES1 ;
 MESS 'NOMBRE DE NOEUDS =' NOES1 ;
 MESS '                   ' ;
*
*QUESTION 03 (01 point)
*~~~~~~~~~~~~~~~~~~~~~~
* Bloquage des déplacements des noeuds de la ligbe AD
 cl1 = bloq depl l4 ;
*
*QUESTION 04 (01 point)
*~~~~~~~~~~~~~~~~~~~~~~
* 
 mod1 = MODE S1 MECANIQUE ELASTIQUE   ;
*
*QUESTION 05 (01 point)
*~~~~~~~~~~~~~~~~~~~~~~~
 mat1 = MATE mod1 young 210000. nu 0.3 ;
*
*QUESTION 06 (02 points)
*~~~~~~~~~~~~~~~~~~~~~~~
*
 rig1 = RIGI mod1 mat1 ;
 rigt = rig1 et cl1 ;
*
*QUESTION 07 (02 points)
*~~~~~~~~~~~~~~~~~~~~~~~
 f1 = press mass mod1 l2 -200. ;
 list f1 ;
 Vec1 = VECT f1  FX FY  vert ;
 TRAC s1 Vec1 TITRE 'efforts sur la structure';
*
*QUESTION 08 (02 points)
*~~~~~~~~~~~~~~~~~~~~~~~
 u1 = reso rigt f1 ;

*QUESTION 09 (02 points)
*~~~~~~~~~~~~~~~~~~~~~~~
*
 def0 = defo u1 ct1 0. rouge ;
 def1 = defo u1 ct1 jaune ;
 titr 'CONFIGURATION DEFORMEE ET NON DEFORMEE' ;
 trace (def1 et def0) ; 
*
*QUESTION 10 (02 points)
*~~~~~~~~~~~~~~~~~~~~~~~
*champ de contraintes
 sig1 = sigma u1 mod1 mat1 ;
 tire 'champ de contraintes sous F1' ;
 trace sig1 mod1 ;
*
*QUESTION 11 (02 points)
*~~~~~~~~~~~~~~~~~~~~~~~
* champ de réactions 
* ~~~~~~~~~~~~~~~~~~
 Rea1  = REAC u1 rigt ;
 list Rea1;
 Vec2 = VECT Rea1  FX FY  rouge;
 TRAC s1 (Vec1 et Vec2) TITRE 'efforts sur la structure';
*
*QUESTION 12 (02 points)
*~~~~~~~~~~~~~~~~~~~~~~~
*chargement f2
 f2 = press mass mod1 l3 100. ;
* chargement total 
 FT = F1 ET F2 ;
 Vec1 = VECT fT  FX FY  vert ;
 TRAC s1 Vec1 TITRE 'efforts sur la structure';

*le nouveau champ de déplacement 
 u2 = reso rigt FT ;
*visualisation de la nouvelle déformée 
 def0 = defo u2 ct1 0. rouge ;
 def2 = defo u2 ct1 Jaune ;
 titr 'CONFIGURATION DEFORMEE ET NON DEFORMEE' ;
 trace (def2 et def0) ; 
* champ de contrainte
 sig2 = sigma u2 mod1 mat1 ;
 tire 'champ de contraintes sous (F1+F2)' ;
 trace sig2 mod1;
*
*QUESTION 13 (02 points)
*~~~~~~~~~~~~~~~~~~~~~~~
* champ de réactions 
* ~~~~~~~~~~~~~~~~~~
 Rea2  = REAC u2 rigt ;
 list Rea2;
 Vec3 = VECT Rea2  FX FY  rouge;
 TRAC s1 (Vec1 et Vec3) TITRE 'efforts sur la structure';
 def2 = defo u2 s1 (Vec1 et Vec3) Jaune ;
 TRAC def2  TITRE 'efforts sur la structure deformee'; 

*
* Ecriture des résultats dans un fichier
* ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
 SI (NEG listing 'N');
 OPTI IMPR 'D:\Enseignements\MEF\MesTP\resuTP1.txt'; 
 MESS 'deplacements aux pts pb et pc';
 u1b = redu u1 pb ; u1c = redu u1 pc ;
 MESS '         ' ;
 MESS 'U1 au noeud pb :'; 
 list u1b ;
 MESS '         ' ;
 MESS 'U1 au noeud pc :';
 list u1c ;
 u2b = redu u2 pb ; u2c = redu u2 pc ;
 MESS '         ' ;
 MESS ' u2 au noeud pb :';
 list u2b ;
 MESS '         ' ;
 MESS 'u2 au noeud pc :';
 list u2c ;
 MESS '         ' ;
 MESS 'reactions'; 
 LIST Rea1;
 MESS '         ' ;
 MESS 'efforts normaux'; 
 LIST sig1;
 MESS '         ' ;
 FINSI;
*FIN;