*
* CORRIGE TP N°02 : Essai de traction de laboratoire 
* ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
* Maillage d'une éprouvette de section (ou de forme)  
* variable avec congé de raccordement
*
* les options d'affichage du défilement des calculs
  opti echo 1 ;
* opti echo 0 ;
* ACTIVATION OU DESACTIVATION DE L'affichage 
* ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
  GRAPH = VRAI ;
* GRAPH = FAUX ;
*
** OPTIONS pour avoir les résultats dans un fichier
* ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
* OPTI TRAC PSC FTRA 'TPN03.psc' ;
*
* 
* QUESTION 01 (04 points)
* ~~~~~~~~~~~~~~~~~~~~~~~
* les options générales des calculs
  OPTI DIME 2 mode plan cont ELEM TRI3 ;
*
* les données sont en N et mm 
* ~~~~~~~~~~~~~~~~~~~~~~~~~~~
*
* Géommétrie de l'eprouvette
* ~~~~~~~~~~~~~~~~~~~~~~~~~~
 long  = 180. ;
 LONG1 = 30. ;
 HAUT1 = 30. ;
 HAUT2 = 12.5 ;
 ray   = 20. ;
*
* bclrem : Boucle de raffinement du maillage
* Compt = 1 : premier maillage grossier
* compt = 2 : second maillage raffiné
* compt = 3 : troisième  maillage trés raffiné
*
 compt = 0 ;
 repete bclrem 3 ;
 compt = compt + 1 ;
*
   si  (compt ega 1) ;
*  r1 est le nombre de segments de l'arc de cercle 
*  de chaque congé de raccordement
*  pour le premier maillage (grossier) on prend r1 = 3
*  pour les deux autres maillages r1 augmente
   r1 = 3   ;
   sinon ;
   r1 = compt * r1 ;
   finsi ;
* n1 et n2 : les nombres de segments des autres tronçons
* du contour de l'eprouvette
  n1 = 2 * r1 ;
  n2 = 6 * r1 ;
*
* les coordonnées des points du contour de l'eprouvette
* ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
  p0  = 0.     0. ;
  p1  = LONG1  0. ;
  yp2 = 0.5*(HAUT1 - HAUT2) ;
  xp2 = ((((ray ** 2.) - ((ray - yp2 ) ** 2.))) ** 0.5) + LONG1 ;
  p2  = xp2     yp2   ;
  xp3 = (long - xp2) ;
  yp3 = yp2 ;
  p3  = xp3  yp3 ;
  p4  = (long - LONG1)  0. ;
  p5  = long 0. ;
  p6  = long HAUT1 ;
  p7  = (long - LONG1)  HAUT1 ;
  p8  =  xp3  (0.5*(HAUT1 + HAUT2))  ;
  xp9 = xp2 ;
  p9  = xp9    (0.5*(HAUT1 + HAUT2))  ;
  p10 = LONG1 HAUT1 ;
  p11 = 0.   HAUT1 ;
  xpc1= xp2 ;
  ypc1= yp2 - ray ;
  pc1 = xpc1   ypc1 ;
  xpc2= long - xpc1 ;
  ypc2= ypc1 ;
  pc2 = xpc2 ypc2 ;
  xpc3= xpc2 ;
  ypc3= (0.5*(HAUT1 + HAUT2)) + ray ;
  pc3 = xpc3   ypc3 ;
  xpc4= xpc1 ;
  ypc4= ypc3;
  pc4 = xpc4   ypc4 ;
*
* les lignes du contour
* ~~~~~~~~~~~~~~~~~~~~~
  l1 = d n1 p0 p1 ;
  l2 = d n2 p2 p3 ;
  l3 = d n1 p4 p5 ;
  l4 = d n1 p5 p6 ;
  l5 = d n1 p6 p7 ;
  l6 = d n2 p8 p9 ;
  l7 = d n1 p10 p11 ;
  l8 = d n1 p11 p0 ;
* les congés de raccordement
* ~~~~~~~~~~~~~~~~~~~~~~~~~~
  c1 = c r1 p1 pc1 p2 ;
  c2 = c r1 p3 pc2 p4 ;
  c3 = c r1 p7 pc3 p8 ;
  c4 = c r1 p9 pc4 p10 ;
*
* le contour de l'éprouvette cntep dans sa totalité
* ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
* attention : cntep doit avoir un sens unique et doit etre fermé
* ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
  cntep = l1 et c1 et l2 et c2 et l3 et l4 et l5 
          et c3 et l6 et c4 et l7 et l8 ;
*
* le maillage de l'eprouvette nommé ici eprv
* ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
  eprv = surf cntep ;
* nbep et nbnd sont respectivt les nombres  
* d'eléments  finis et de noeuds du maillage eprv 
  nbep = nbel eprv ;
  nbnd = nbno eprv ;
*
* tracé du maillage
* ~~~~~~~~~~~~~~~~~
  si graph ;
  titr 'Maillage eprouvette nbre elts='nbep'nbre noeuds='nbnd;
  trac eprv ;
  finsi ;
*
* fin bclrem ;
*
* QUESTION 02 (01 point)
* ~~~~~~~~~~~~~~~~~~~~~~~ 
 cl1 = bloq DEPL   l8 ;
*
* QUESTION 03 (01 point)
* ~~~~~~~~~~~~~~~~~~~~~~~ 
 mod1 = mode eprv mecanique elastique ;
*
* QUESTION 04 (01 point)
* ~~~~~~~~~~~~~~~~~~~~~~~ 
 mat1 = mate mod1 nu 0.3 young 210000.  ;
*
* QUESTION 05 (02 points)
* ~~~~~~~~~~~~~~~~~~~~~~~ 
 rig1 = rigi mod1 mat1 ;
 rigt = rig1 et cl1 ;
*
* QUESTION 06 (02 points)
* ~~~~~~~~~~~~~~~~~~~~~~~ 
 f1 = press mass mod1 l4 -200. ;
 Vec1 = VECT f1  FX FY  vert ;
 TRAC EPRV Vec1 TITRE 'efforts sur la structure';
*
* QUESTION 07 (01 point)
* ~~~~~~~~~~~~~~~~~~~~~~~ 
 u1 = reso rigt f1 ;
*
* QUESTION 08 (02 points)
* ~~~~~~~~~~~~~~~~~~~~~~~ 
 def0 = defo u1 cntep 0.;
 def1 = defo u1 cntep 100. ;
 def1 = def1 coul rouge ;
 titr '  deformee de l eprouvette tendue en rouge';
 trac ( def1 et def0 ) ;
*
* QUESTION 09 (02 points)
* ~~~~~~~~~~~~~~~~~~~~~~~ 
 sig1 = sigm u1 mod1 mat1 ;
 titr 'champs de contraintes nbel='nbep;
 trac sig1 mod1 ;
* on peut également repréenter le champ de contraintes sur
* la configuration déformée
 def2 = defo u1 eprv  ;
 titr 'champs de contraintes SUR DEFORMEE nbel='nbep;
 trac sig1 def2 mod1 ;
*
* QUESTION 10 : champ de réactions (01 point)
* ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~    
 Rea1  = REAC u1 rigt ;
 list Rea1;
 Vec2 = VECT Rea1  FX FY  rouge;
 TRAC EPRV (Vec1 et Vec2) TITRE 'efforts sur la structure';
*
* QUESTION 11 : Observation et analyse des résultat (01 point)
* ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
* Il s'agit de comparer les résultats obtenus à partir des trois 
* maillages sans oublier de tenir cpte des temps d'éxecution ainsi  
* que du nbre d'elements    
*
 fin bclrem ;

* QUESTION 12 : Calculs avec des éléments QUA4 (02 points)
* ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
*   Refaire les calculs précédents avec cette fois OPTI  ELEM QUA4 
 OPTI  ELEM QUA4 ;
*
* Deuxieme Boucle de raffinement de maillage
* Compt = 1 : premier maillage grossier
* compt = 2 : second maillage raffiné
* compt = 3 : troisième  maillage trés raffiné
*
 compt = 0 ;
 repete bclrm2 3 ;
 compt = compt + 1 ;
*
   si  (compt ega 1) ;
*  r1 est le nombre de segments de l'arc de cercle 
*  de chaque congé de raccordement
*  pour le premier maillage (grossier) on prend r1 = 3
*  pour les deux autres maillages r1 augmente
   r1 = 3   ;
   sinon ;
   r1 = compt * r1 ;
   finsi ;
* n1 et n2 : les nombres de segments des autres tronçons
* du contour de l'eprouvette
  n1 = 2 * r1 ;
  n2 = 6 * r1 ;
*
* les lignes du contour
* ~~~~~~~~~~~~~~~~~~~~~
  l1 = d n1 p0 p1 ;
  l2 = d n2 p2 p3 ;
  l3 = d n1 p4 p5 ;
  l4 = d n1 p5 p6 ;
  l5 = d n1 p6 p7 ;
  l6 = d n2 p8 p9 ;
  l7 = d n1 p10 p11 ;
  l8 = d n1 p11 p0 ;
* les congés de raccordement
* ~~~~~~~~~~~~~~~~~~~~~~~~~~
  c1 = c r1 p1 pc1 p2 ;
  c2 = c r1 p3 pc2 p4 ;
  c3 = c r1 p7 pc3 p8 ;
  c4 = c r1 p9 pc4 p10 ;
*
  cntep = l1 et c1 et l2 et c2 et l3 et l4 et l5 
          et c3 et l6 et c4 et l7 et l8 ;
*
  eprv = surf cntep ;
  nbep = nbel eprv ;
  nbnd = nbno eprv ;
*
  si graph ;
  titr 'Maillage eprouvette nbre elts='nbep'nbre noeuds='nbnd;
  trac eprv ;
  finsi ;
* fin bclrm2 ;
*
 cl1 = bloq DEPL   l8 ;
 mod1 = mode eprv mecanique elastique ;
 mat1 = mate mod1 nu 0.3 young 210000.  ;
 rig1 = rigi mod1 mat1 ;
 rigt = rig1 et cl1 ;
 f1 = press mass mod1 l4 -200. ;
 Vec1 = VECT f1  FX FY  vert ;
 TRAC EPRV Vec1 TITRE 'efforts sur la structure';
 u1 = reso rigt f1 ;
 def0 = defo u1 cntep 0.;
 def1 = defo u1 cntep 100. ;
 def1 = def1 coul rouge ;
 titr '  deformee de l eprouvette tendue en rouge';
 trac ( def1 et def0 ) ;
 sig1 = sigm u1 mod1 mat1 ;
 titr 'champs de contraintes nbel='nbep;
 trac sig1 mod1 ;
 Rea1  = REAC u1 rigt ;
 list Rea1;
 Vec2 = VECT Rea1  FX FY  rouge;
 TRAC EPRV (Vec1 et Vec2) TITRE 'efforts sur la structure';
 fin bclrm2 ;
*
* QUESTION 13 : Calcul sur le maillage Quart de l'eprouvette (02pts)
* ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~ 
* CREATION De nouveaux  POINTS D'APPUI DU MAILLAGE de ce quart
* ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
opti elem qua4 ;
xP12  = 0.5 * long  ;
yP12  = yP2 ;
P12   = xP12   yP12  ;
xP13 = xP12   ;
yP13 = 0.5 * haut1 ;
P13  = xP13  yP13  ;
xP14 = xP2 ;
yP14 = yP13 ;
P14  = xP14  yP14  ;
P15        = 0.   (0.5 * HAUT1) ;
xpc1 = xP2 ;
ypc1 = yP2 - ray ;
pc1  = xpc1   ypc1 ;
*
* CREATION DES LIGNES D'APPUI DU MAILLAGE
* ---------------------------------------
* -----------------------------------------------
NLONG    =  32   ;
NHAUT    =  5    ;
NQC      =  20   ;
L1415     = DROI (NQC - NHAUT) P14 P15  ;
L150     = DROI NHAUT P15  P0 ;
CE1      = CERC NQC P1  pc1 P2 ;
SUGI1    = REGL  'DINI' 2.0 'DFIN' 2.0 (INVE CE1) (L1415 ET L150) ;
L212     = DROI NLONG P2 P12  ;
L1314     = DROI NLONG P13 P14 ;
L142     = (CONT SUGI1) ELEM COMPRIS P14 P2 ;
NBLcf    = NBEL L142 ;
L1213     = DROI NBLcf P12  P13 ;
SUGI2    = DALL L212 L1213 L1314 L142 plan ;
SUGI     = SUGI1 ET SUGI2 ;
SUGS     = SUGI SYME 'DROI' P15  P13 ;
SUG      = SUGI ET SUGS ;
SUD      = SUG  SYME 'DROI' P12  P13 ;
EPRV     = SUG ET SUD ;
QPRV = SUGI ;
CNTQP = CONT QPRV ;
ELIM eprv 1.E-9 ;
SI graph ;
  TRAC QPRV 'TITR' 'Maillage DU QUART de l eprouvette' ;
  TRAC (cont QPRV) 'TITR' ' contour DU QUART de l eprouvette' ;
  TRAC EPRV 'TITR' 'Maillage de l eprouvette' ;
  TRAC (cont EPRV) 'TITR' 'contour de l eprouvette' ;
FINSI ;
modQ = mode Qprv mecanique elastique ISOTROPE  ;
*
matQ = mate modQ nu 0.3 young 210000.  ;
*
clQ1 = (bloq UX   L1213) ET (BLOQ UY (L1314 ET L1415)) ;
*
fQ1 = press mass modQ L150  -200. ;
*
*
rigQ = rigi modQ matQ ;
*
rigQt = rigQ et clQ1 ;
*
uQ = reso rigQt fQ1 ;
*
*OPTI TRAC PSC FTRA 'EPRV RESOU.psc' ;
TITR ' maillage QUART eprouvette nbre elts=' nbep 'nbre noeuds=' nbnd ;
trac Qprv ;
sigQ1 = sigm uQ modQ matQ ;
NBEQ = NBEL QPRV ;
NBNQ = NBNO QPRV ;
titr 'champs contraintes nbre elts='nbep'nbre noeuds='NBNQ;
trac sigq1 modq ;
def0 = defo uq cntqp 0.;
def1 = defo uQ cntqp ;
def1 = def1 coul rouge ;
titr '  deformee avec nbel='nbep;
trac ( def1 et def0 ) ;
* Extraction de la valeur maximale du champ de contraintes de VonMises
 VMIS1  =  VMIS  MODQ SIGQ1 ;
* extraction de l'element contenant la contrainte maximale de VonMises
 Elmax = VMIS1 ELEM 'MAXI' ;
* Reduction du champ VMIS1 à Elmax
 VMEL1 = REDU VMIS1 ELMAX ;
* tracé en rouge de l'element contenant la valeur maxi de VMIS1
 Smax = maxi VMEL1 ;
 mess '                           ' ;
 mess ' valeur maximale de la contrainte de VonMISES=' ;
 MESS ' Smax ='Smax' MPa' ;
 mess '                           ' ;
 TITR 'en rouge element contenant CONTR MAXI de VMIS en MPa Smax='Smax;
 TRAC (qprv et (elmax coul rouge)) ;