*****************************************************
*  treillis plan 
*  Etude statique en petites déformations
*  fichier : TP03 treillis.dgibi
*              
* options générales des calculs 
* ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
OPTI DIME 2 ELEM SEG2 MODE PLAN CONT;
OPTI EPSI 'LINEAIRE';
*
OPTI ECHO 0 ;
*Les données sont en KN et en cm 
* ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
  a1 = 100. ; phi= 2. ; S1 = PI*((0.5*phi)**2);
  yEp = 21000.; nup = 0.3 ; fya = 23.5 ; 
  F1 = 30.; echel= a1/(3.*F1);
*
* calcul du moment d'inertie en cm^4
* ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
   Iyy = PI*(phi**4)/64. ;
*
* solution theorique de la RDM
* ~~~~~~~~~~~~~~~~~~~~~~~~~~~~
        uth3 = F1*a1*(1+(1/(2*(2**0.5))))/(yEp*S1);
        vth3 = -1*F1*a1/(yEp*S1*(2*(2**0.5)));
*
*OPTI ECHO 0;
*****************************************************
*
*  géométrie et maillage
* ~~~~~~~~~~~~~~~~~~~~~~
xx = a1*(2**0.5)/2.;
P1 = 0. 0.;
P2 = (2*xx) 0.;
P3 = xx xx;
L1 = DROI 1 P1 P2 ;
L2 = DROI 1 P1 P3 ;
L3 = DROI 1 P2 P3 ;
Treil = L1 ET L2 ET L3;
*****************************************************
*  
* Modèle et Caracteristiques mécaniques
* ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
mod1 = MODE Treil mecanique elastique isotrope Barre;
mat1 = MATE mod1 YOUN yEp NU nup ;
car1 = CARA mod1 SECT S1 ;
matot1 = mat1 ET car1;
*****************************************************
*
*   conditions aux limites
* ~~~~~~~~~~~~~~~~~~~~~~~~
cl1 = BLOQ DEPL P1;
cl2 = BLOQ UY P2;
clt = cl1 ET cl2;
cha1 = FORC  (F1 0.)  P3 ;
Vec1 = VECT  cha1 echel FX FY vert;
TRAC Treil Vec1  TITRE 'structure et chargement';
******************************************************
*
* Matrice  de raideur et resolution
* ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
raidt = RIGI mod1 matot1 ; 
dep1 = RESO (raidt ET clt) cha1;
******************************************************
*
* Post-traitement des résultats
* ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
* déformée
* ~~~~~~~~
LIST 'RESUME' dep1;
u3 = EXTR dep1 Ux P3;
v3 = EXTR dep1 Uy P3;
MESS ' U au noeud 3 :'u3; MESS 'theorie :'uth3;
MESS ' V au noeud 3 :'v3; MESS 'theorie :'vth3;
def0 = DEFO (1.e1*dep1) Treil 0. bleu;
def1 = DEFO (1.e1*dep1) Treil rouge;
TRAC (def0 ET def1) TITRE 'deformee de la structure en mm'; 
* réactions
* ~~~~~~~~~
Rea1  = REAC dep1 (raidt ET clt);
list Rea1;
Vec2 = VECT Rea1 echel FX FY  rouge;
TRAC Treil (Vec1 et Vec2) TITRE 'efforts sur la structure';
* efforts normaux
* ~~~~~~~~~~~~~~~
sig1  = SIGMA mod1 dep1 matot1;
list sig1;
nxx = EXCO  EFFX  sig1 ;
TRAC def0 nxx mod1 TITRE 'effort Normal en KN';
*
* VERIFICATION DE LA STABILITE AU FLAMBEMENT DE LA BARRE COMPRIMEE L3
* ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
* la barre comprimee etant uniquement L3, les autres barres L1 et L2
* sont tendues
*
* Extraction de la valeur de l'effort de compression maximale
 Nsol = Abs (Mini sig1) ;
* Calcul de la valeur theorique l'effort Normal critique d'Euler
* ou de l'effort Normal resistant pour la barre comprimée l3
  Nres = yEp * Iyy * ((PI / (mesu L3))**2) ;
* Comparaison des deux efforts sollicitants et résistants
 MESS 'EFFORT NORMAL MAX DE COMPRESSION NSOL='NSOL'KN';
 MESS 'EFFORT NORMAL RESISTANT D EULER NRES='NRES'KN';

 si (Nsol <eg Nres) ;
 MESS 'STABILITE AU FLAMBEMENT VERIFIEE' ;
 MESS 'DONC BARRE DE DIAMETRE ='PHI'CM VERIFIEE V A V INSTABILITES';
 SINON ;
  MESS 'ATTENTION STABILITE AU FLAMBEMENT NON VERIFIEE' ;
  MESS 'AUGMENTEZ LE DIAMETRE PHI ET REFAITES LES CALCULS';
 FINSI ; 
*
* VERIFICATION VIS  A VIS DE LA RESISTANCE DE TOUTES LES BARRES
* ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
* Calcul de la valeur de l'effort normal maximal dans la structure
  Nmax = MAXI (ABS SIG1 ) ;
* calcul de la valeur de la contrainte max EN MPa
  smax = 10. * Nmax / s1 ;
* CALCUL DE LA VALEUR DE CONTRAINTE ADMISSIBLE EN MPa
  SGAD = 10. * (0.5 * fya) ;
*
** Comparaison des deux contraintes max appliquees et admissibles
 MESS 'CONTRAINTES NORMALES MAX DE COMPRESSION SMAX='smax'MPa';
 MESS 'CONTRAINTES NORMALES ADMISSIBLES SGAD='SGAD'MPa';
 si (smax <eg sgad) ;
 MESS 'RESISTANCE DES BARRES VERIFIEE VIS A VIS CONTRAINTE ADMISSIBLE';
 MESS 'DONC BARRES DIAMETRE ='PHI'CM VERIFIEES V A V RESISTANCE';
 SINON ;
 MESS 'ATTENTION ' ;
 MESS 'RESISTANCE DES BARRES NON VERIFIEE VIS A VIS CONTR ADMISSIBLE';
 MESS 'AUGMENTEZ LE DIAMETRE PHI ET REFAITES LES CALCULS';
 FINSI ; 
*
* pour avoir les résultats dans un fichier
* ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
listing ='N'; 
SI (NEG listing 'N');
* nota : le chemin indiqué ci dessous est à titre indicatif
* il peut changer d'un ordinateur à un autre
* ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
OPTI IMPR 'D:\Enseignements\MEF\MesTP\resulTP2.txt'; 
MESS 'deplacements'; LIST dep1;
MESS ' U au noeud 3 :'u3; MESS 'theorie :'uth3;
MESS ' V au noeud 3 :'v3; MESS 'theorie :'vth3;
MESS 'reactions'; LIST Rea1;
MESS 'effort normal'; LIST sig1;
*
* Comparaison des deux efforts sollicitants et résistants
 MESS 'EFFORT NORMAL MAX DE COMPRESSION NSOL='NSOL'KN';
 MESS 'EFFORT NORMAL RESISTANT D EULER NRES='NRES'KN';
*
  si (Nsol <eg Nres) ;
   MESS 'STABILITE AU FLAMBEMENT VERIFIEE' ;
   MESS 'LA BARRE DE DIAMETRE ='PHI'CM EST VERIFIEE' ;
  SINON ;
   MESS 'ATTENTION STABILITE AU FLAMBEMENT NON VERIFIEE' ;
   MESS 'AUGMENTEZ LE DIAMETRE PHI ET REFAITES LES CALCULS';
  FINSI ; 
FINSI;
*
*FIN;